var milled;
var left;
var scale;

macro "Show Dialog... [b]" {

//import image sequence
//run("Image Sequence...", "number=999 starting=1 increment=1 scale=100 file=tif");

//Set scale and milling status automagically
//This macro is for use with 50x images
//At either 1024 or 2048 resolution
//and 1.7448 or 0.8745 microns per pixel
//the reason that the pixel sizes aren't exactly 2* is that the SEM was recalibrated between runs.

res = getHeight();

if (res==1024)
	scale = 1.7448;
else if (res==2048)
	scale = 0.8745;
//failsafe value
else
	scale = 1;

if (res == 1024)
	milled = "p";
else if (res == 2048)
	milled = "m";
else
	milled = "u";

//need to have a line selection for line width to work
makeLine(512,512,612,512);

if (res==1024)
	run("Line Width...", "line=25");
else if (res==2048)
	run("Line Width...", "line=50");
else
	run("Line Width...", "line=1");

//Make a dialog box
Dialog.create("Specimen Information");
Dialog.addCheckbox("Lateral to left (uncheck if to right)", true);
Dialog.addNumber("Scale", scale, 4, 6, "µm / pixel");
Dialog.show();
left = Dialog.getCheckbox();
scale = Dialog.getNumber();
setVoxelSize(scale, scale, 1, "micron");

//set logical values
if (left==true)
	left = 1;
else
	left = 0;
}

macro "Calcified Cartilage [t]" {
    requires("1.34h");                           
    var bmmd;
    var fraction;

//get the pixel information from inside the ROI    
 getRawStatistics(count, mean, min, max, std, histogram);
 row = nResults;

//get the number of image fields in the stack from ImageJ
fields = nSlices();
   
//use this line if dealing with a stacked series of images
name=getMetadata();

//use this line if dealing with single images
//    name = getTitle();

//  The following section gets useful information from the filename
   horse = substring(name, 0, 2);
   setResult("Horse ID", row, horse);
   leg = substring(name, 2, 3);
   setResult("Leg", row, leg);
   section = substring(name, 3, 4);
   setResult("Slice", row, section);
   ni = getSliceNumber();

//use these lines to manually control the threshold
lower=1;
upper=255;

    for (k=0; k<lower; k++) {
        background = background + histogram[k];
        fraction = (count - background) / count;
        setResult("Vfc ", row, fraction);         
    }
   
    for(j=lower; j<upper; j++) {
        cumulative = cumulative + histogram[j];
         av = av + j * histogram[j];
        bmmd = av / cumulative;
        setResult("Mean Matrix", row, bmmd);
    }
   
modep=0;
    mode = 0;
    for (p=lower; p<upper; p++) {
   
        if (mode < histogram[p]) {
        mode = histogram[p];
        setResult("Mode", row, p);
        modep = p;
    }
    }

    setResult("Mean ROI ", row, mean);
 
//get the coordinates of the ends of the straight line selection
getLine(a,b,c,d,w);

//calculate line length - go pythagoras
thickness=scale*sqrt((a-c)*(a-c)+(b-d)*(b-d));
setResult("Thickness", row, thickness);

//Calculate relative position from left, lateral is always left, image sequences start on left

if (left == 1) 
	pos = ni / fields;
else if (left == 0)
	pos = (fields - ni +1) / fields;

setResult("Pos", row, pos);
setResult("Finish", row, milled);

//still can't get strings into the results table...
//updateResults();

//the next line prints results in a log window 
print(horse, " \t", leg, "\t", section, "\t", milled,"\t", modep, " \t", mean, " \t", bmmd, " \t", fraction, "\t", thickness, "\t", pos, " \n");                

//draw a 250 micron radius circle to guide unbiased placement of next ROI
r=500/scale;
x=a-r/2;
y=b-r/2;
makeOval(x,y,r,r);



}