//DcmRenamer
//ImageJ macro to rename DICOM format images
//and corresponding bitmap thumbnails
//using the string from a DICOM header tag.
//Copyleft Michael Doube 2007
 

requires("1.39f");
setBatchMode(true);
open();
path = File.directory();

//Hit [i] with a DICOM image open and edit the following line
tag = "0010,0010";

close();

function getTag(tag) {
     info = getImageInfo();
     index1 = indexOf(info, tag);
     if (index1==-1) return "";
     index1 = indexOf(info, ":", index1);
     if (index1==-1) return "";
     index2 = indexOf(info, "\n", index1);
     value = substring(info, index1+1, index2);
     return value;
 }

list = getFileList(path);
for (i=0; i<list.length; i++){
   if(endsWith(list[i], '.dcm')){
       open(list[i]);
       newtitle = replace(getTag(tag),'^','_');
       while (startsWith(newtitle, ' ') || startsWith(newtitle, '_'))
newtitle = substring(newtitle, 1, lengthOf(newtitle));
       while (endsWith(newtitle, ' ') || endsWith(newtitle, '_'))
newtitle = substring(newtitle, 0, lengthOf(newtitle)-1);
       newtitle = replace(newtitle, ' ', '_');
       close();
       print("New title string = ", newtitle);

       dcmfile = path+newtitle+".dcm";

       replicates = 0;
       while (File.exists(dcmfile)){
           dcmfile = path+newtitle+"_"+toString(replicates)+".dcm";
           replicates++;
       }

       print("Renaming ", path+list[i], "to ", dcmfile);

       if(File.rename(path+list[i], dcmfile)){
           print("Renamed DCM file");
       } else {
           print("Failed to rename DCM file");
       }

       thumbnail = replace(list[i], ".dcm", ".bmp");
       bmpfile = replace(dcmfile, ".dcm", ".bmp");

       print("Renaming ", path+thumbnail, "to ", bmpfile);

       if (File.rename(path+thumbnail, bmpfile)){
           print("Renamed BMP file");
       } else {
           print("Failed to rename BMP file");
       }
   }
}