// "Radial Histogram"
// Takes a CSV (comma-separated values) list of angles and values
// and draws a radial histogram. A sample list is available at
//     http://rsb.info.nih.gov/ij/macros/data/angles.csv

requires("1.37v");

progress("Open file, which must be a csv list in (angle, value) format", 1, 10);
string = File.openAsString("");
start = getTime;

progress("Split the CSV file into an array of lines", 2, 10);
lines = split(string, "\n");

//initialise some variables
n = lengthOf(lines);
theta = newArray(n);
r = newArray(n);

//number of divisions
Dialog.create("Set Divisions");
Dialog.addMessage("Your file contains "+n+" entries.\nEnter the number of graph divisions:");
Dialog.addNumber ("Divisions", 12);
Dialog.show();
divs = Dialog.getNumber();

wedgetheta = 360 / divs;
counts = newArray(divs);

for (i=0; i<n; i++){
   thetar= split(lines[i], "\,");
   theta[i] = parseFloat(thetar[0]);

//sort each entry into bins in the counts array
    for (j=0; j<divs; j++){
        upper = 360*j/divs + 360/(2*divs);
        lower = 360*j/divs - 360/(2*divs);
        if(theta[i]<upper && theta[i]>=lower){
            counts[j]++;
        }
    }
//handle the half-div prior to 360 deg (-divs/2)
    upper = 360;
    lower = 360*(1-1/(divs*2));
        if(theta[i]<upper && theta[i]>=lower){
            counts[0]++;
        }
}

progress("Find the maximum count (to determine the outer boundary)", 3, 10);

maxcount = 0;
for(i=0; i<divs; i++) {
    if(counts[i]>maxcount) maxcount = counts[i];
}

radius = 506;
margin = 6;
image = 2*(radius+margin);

//Draw the new image
setBatchMode(true);
newImage("Untitled", "8-bit White", image, image, 1);
if (File.exists(getDirectory("imagej")+"luts/Orange Hot.lut"))
    run("Orange Hot");
else
    run("Fire");

xp = newArray(divs);
yp = newArray(divs);

progress("Draw the points", 5, 10);
for (i=0; i<divs; i++) {
    radtheta = 2*PI*i/divs;
    unitr = counts[i]/maxcount;
    x = radius + margin + unitr*cos(radtheta)*radius;
    y = radius + margin - unitr*sin(radtheta)*radius;
    setColor(0);
    setLineWidth(1);
    drawLine(margin+radius,margin+radius,x,y);
    xp[i] = x;
    yp[i] = y;
}

//join the dots
for (i=0; i<(divs-1); i++){
setColor(0);
drawLine(xp[i],yp[i],xp[i+1],yp[i+1]);
}
drawLine(xp[0],yp[0],xp[divs-1],yp[divs-1]);

progress("Draw unit circle and axis", 6, 10);
setColor(50);
setLineWidth(1);
drawOval(margin,margin,2*radius,2*radius);
drawLine(0,radius+margin, image, radius+margin);
drawLine(radius+margin,0, radius+margin, image);
setBatchMode(false);
progress(""+n+" lines processed", 7, 10);
wait(2000);
exit;

function progress(msg, current, end) {
    showStatus(msg);
    showProgress(current, end);
}