// "Rectangular Scattergraph"
// Takes a CSV (comma-separated values) list of (x,y) coordinates
// and draws a scattergraph.

requires("1.37v");

progress("Open file, which must be a csv list in (value x, value y) format", 1, 10);
string = File.openAsString("");
start = getTime;

progress("Split the CSV file into an array of lines", 2, 10);
lines = split(string, "\n");

//initialise some variables
n = lengthOf(lines);
x = newArray(n);
y = newArray(n);
xmax = 0;
ymax = 0;

progress("Find the maximum x and y (to determine the outer boundary)", 3, 10);

for (i=0; i<n; i++){
   xy = split(lines[i], "\,");
   x[i] = parseFloat(xy[0]);
   y[i] = parseFloat(xy[1]);
   if (abs(x[i]) > xmax) xmax = abs(x[i]);
   if (abs(y[i]) > ymax) ymax = abs(y[i]);
}

radius = 506;
margin = 6;
image = 2*(radius+margin);

//Draw the new image
setBatchMode(true);
newImage("Untitled", "8-bit Black", image, image, 1);
if (File.exists(getDirectory("imagej")+"luts/Orange Hot.lut"))
    run("Orange Hot");
else
    run("Fire");

progress("Save point coordinates in arrays", 4, 10);
xp = newArray(n);
yp = newArray(n);
zp = newArray(n);
for (i=0; i<n; i++) {
//   radtheta = theta[i]*2*PI / 360;
   unitx = x[i]/xmax;
   unity = y[i]/ymax;
   xp[i] = radius + margin + unitx*radius;
   yp[i] = radius + margin - unity*radius;
}

progress("Draw the points", 5, 10);
for (i=0; i<n; i++) {
   x=xp[i]; y=yp[i];
   setPixel(x, y, getPixel(x,y)+1);
}

progress("Find neighborhood densities", 6, 10);
r=20;
min = 999999;
max = 0;
for (i=0; i<n; i++) {
   makeOval(xp[i]-r, yp[i]-r, r*2, r*2);
   getStatistics(count, mean);
   zp[i] = mean;
   if (mean<min) min = mean;
   if (mean>max) max = mean;
}
run("Select None");

progress("Draw each point in a color proportional to neighborhood density", 8, 10);
scale = 200/(max-min);
for (i=0; i<n; i++) {
    if (55+(zp[i]-min)*scale < 255 ) setColor(55+(zp[i]-min)*scale);
    else setColor(255);
   fillRect(xp[i], yp[i], 2,2);
}

progress("Draw unit circle and axis", 9, 10);
setColor(200);
//drawOval(margin,margin,2*radius,2*radius);
drawLine(0,radius+margin, image, radius+margin);
drawLine(radius+margin,0, radius+margin, image);
setBatchMode(false);
//print(getTime-start);
progress(""+n+" lines processed", 10, 10);
wait(2000);
exit;

function progress(msg, current, end) {
    showStatus(msg);
    showProgress(current, end);
}