//VolumeSlicer
//Generate sequences of volume renderings for animation
//Michael Doube
//m.doube at qmul.ac.uk

//ImageJ macro to interface with Kai Uwe Barthel's Volume Viewer plugin
//based on his macro, RotatingVolume.txt
//http://rsb.info.nih.gov/ij/plugins/volume-viewer.html

//Modified: 2007-04-11 17:58 BST

//List of default values

var display_mode;
var lut;
var scale_min = 0.5;
var scale_max = 1.5;
var zaspect = 1;
var depth = 6;
var minthreshold = 128;
var maxthreshold = 128;
var mindist = -100;
var maxdist = 100;
var n = 10;
var xposstart = 120;
var zposstart = 15;
var xrottot = 0;
var zrottot = 60;
var axes = 0;
var markers = 0;
var name = -1;

macro "VolumeSlicer.txt [b]" {
requires("1.33r");
saveSettings();
if (nImages==0) exit("No images are open"); 
//List all the open images
titles = newArray(nImages);
for (i=1; i<=nImages; i++) {
 	selectImage(i);
	titles[i-1]=getTitle;
}
for (i = 0; i<lengthOf(titles); i++){
	if (titles[i] == name) p = i;
	else p = 0;
}

//Construct a dialog box
Dialog.create("Volume Rendering Set Up");
Dialog.addChoice("Select Stack", titles, titles[p]);
display_modes = newArray("Slice Nearest Neighbour", "Slice Trilinear", "Slice & Borders", "Slice & Volume Dots", "Volume Dots", "Volume I", "Volume II");
luts = newArray("Original", "Grayscale", "Spectrum LUT", "Fire LUT", "Thermal LUT");
Dialog.addChoice("Render Mode", display_modes, display_modes[5]);
Dialog.addChoice("LUT", luts, luts[0]);
Dialog.addNumber("Start Scale", scale_min);
Dialog.addNumber("End Scale", scale_max);
Dialog.addNumber("Z Aspect", zaspect);
Dialog.addNumber("Depth", depth);
Dialog.addNumber("Start Threshold", minthreshold);
Dialog.addNumber("End Threshold", maxthreshold);
Dialog.addNumber("Start Distance", mindist);
Dialog.addNumber("End Distance", maxdist);
Dialog.addNumber("Number of Slices", n);
Dialog.addNumber("X Position", xposstart);
Dialog.addNumber("Z Position", zposstart);
Dialog.addNumber("X Rotation", xrottot);
Dialog.addNumber("Z Rotation", zrottot);
Dialog.addCheckbox("Show Axes", axes);
Dialog.addCheckbox("Show Markers", markers);
Dialog.show();
name = Dialog.getChoice();
selectWindow(name);
stack1 = getImageID;
stack2 = 0;
if (nSlices==1) exit("Stack required");
display_mode = Dialog.getChoice();
for (i = 0; i<lengthOf(display_modes); i++){
	if (display_modes[i] == display_mode) display_mode = i;
}
lut = Dialog.getChoice();
for (i = 0; i<lengthOf(luts); i++){
	if (luts[i] == lut) lut = i;
}
scale_min = Dialog.getNumber();
scale_max = Dialog.getNumber();
zaspect = Dialog.getNumber();
depth = Dialog.getNumber();
minthreshold = Dialog.getNumber();
maxthreshold = Dialog.getNumber();
mindist = Dialog.getNumber();
maxdist = Dialog.getNumber();
n = Dialog.getNumber();
xposstart = Dialog.getNumber();
zposstart = Dialog.getNumber();
xrottot = Dialog.getNumber();
zrottot = Dialog.getNumber();
axes = Dialog.getCheckbox();
markers = Dialog.getCheckbox();
scalestep = (scale_max-scale_min)/n;
diststep = (maxdist-mindist) / n;
xrotstep = xrottot / n;
zrotstep = zrottot / n;
threshstep = (maxthreshold-minthreshold)/n;

  setBatchMode(true);
  dist = mindist;
  for (i=0; i<n; i++) {
    showProgress(i, n);
    selectImage(stack1);
    scale = scale_min + i*scalestep;
    dist = mindist + i*diststep;
    xpos = xposstart + i*xrotstep;
    zpos = zposstart + i*zrotstep;
    threshold = minthreshold + i*threshstep;
    run("Volume Viewer", 
      "display_mode="+display_mode+" axes="+axes+" markers="+markers+" lut="+lut+" scale="+scale+" z-aspect="+zaspect+" dist="+dist+" depth="+depth+" thresh="+threshold+" angle_x="+xpos+" angle_z="+zpos );
    run("Copy");
    w = getWidth; h = getHeight;
    close();     
    if (stack2==0) {
      run("New...", "name=Plots type=RGB Color width="+w+" height="+h+" slices=1");
      stack2 = getImageID;
    } else {
      selectImage(stack2);
      run("Add Slice");
    }
    run("Paste");
  }
  setSlice(1);
  setBatchMode(false);
  restoreSettings();
}